ASP智能搜索的实现--西部E网weste.net

用ASP实现搜索引擎的功能是一件很方便的事，可是，如何实现类似3721的智能搜索呢？比如，当在搜索条件框内输入“中国人民”时，自动从中提取“中国”、“人民”等关键字并在数据库内进行搜索。看完本文后，你就可以发现，这个功能实现起来竟然是如此的简单。OK，Follow Me！
　　第一步，我们要建立一个名为db_sample.mdb的数据库（本文以Access2000数据库为例），并在其中建立表T_Sample。表T_Sample包括如下字段：
　　　　ID　　　　　　自动编号
　　　　U_Name　　文本
　　　　U_Info　　　备注
　　第二步，我们开始设计搜索页面Search.asp。该页面包括一个表单（Frm_Search），表单内包括一个文本框和一个提交按钮。并将表单的method属性设为“get” ，action属性设为“Search.asp"，即提交给网页自身。代码如下：
　　
　　<form name="frm_Search" method="get" action="Search.asp">
　　　请输入关键字：
　　　 <input type="text" name="key" size="10">
　　　 <input type="submit" value="搜索">
　　</form>
　　下面，就进入了实现智能搜索的关键部分。
　　首先，建立数据库连接。在Search.asp的开始处加入如下代码：
　　<%
　　Dim strProvider,CNN
　　　　strProvider="Provider=Microsoft.Jet.OLEDB.4.0;Data Source="
　　　　strProvider=strProvider & Server.MapPath("\") & "\data\db_Sample.mdb"　’假设数据库存放在主页根目录下的data目录下
　　　　Set CNN = Server.CreateObject("ADODB.connection")
　　　　CNN.Open strProvider　’打开数据库连接
　　%>
　　接下来，判断 ASP页所接收到的数据，并在数据库中进行搜索。
　　<%
　　Dim S_Key,RST,StrSQL
　　　　S_Key = Trim(Request("key"))　 ’得到搜索关键字的值
　　　　If S_Key <>"" then
　　　　　　Set RST=Server.CreateObject("ADODB.RecordSet")
　　　　　　StrSQL=AutoKey(S_Key)　’此处使用自定义函数 AutoKey()，该函数为实现智能搜索的核心
　　　　　　RST.Open StrSQL,CNN,3,2　’得到搜索后的记录
　
　　　　　　If RST.BOF And RST.EOF Then
　　%>
　　　　　　　　<font color="#FF0000">未找到任何结果！！！</font>
　　<%
　　　　　　　　Else
　　%>
　　　　　　　　　　搜索名称为“<font color="#FF0000"><%= S_Key %></font>”的项，共找到 <font color="#FF0000"><%= RST.RecordCount %></font> 项：<p>
　　<%
　　　　　　　　　　While Not RST.EOF　 ’遍历整个记录集，显示搜索到的信息并设置链接
　　%>
　　　　　　　　　　　　
　　　　　　　　　　　　<font style="font: 12pt 宋体"><a href="info.asp?ID=<%= RST("ID") %>" target="_blank"><%= RST("U_Name") %></a></font><br>　
　　　　　　　　　　　　
　　　　　　　　　　　　<font style="font: 9pt 宋体"><%= Left(RST("U_Info"),150) %></font><p>　
　　<%
　　　　　　　　　　　　RST.MoveNext
　　　　　　　　　　Wend
　　　　　　　　　　RST.Close
　　　　　　　　　　Set RST=Nothing
　　　　　　End If
　　　　End If
　　%>
　　在上面的代码中，有一个自定义函数 AutoKey ，该函数是实现智能搜索的核心所在。代码如下：
　　<%
　　Function AutoKey(strKey)
　　　　CONST lngSubKey=2
　　　　Dim lngLenKey, strNew1, strNew2, i, strSubKey

　　　　’检测字符串的合法性，若不合法则转到出错页。出错页你可以根据需要进行设定。
　　　　if InStr(strKey,"=")<>0 or InStr(strKey,"`")<>0 or InStr(strKey,"’")<>0 or InStr(strKey," ")<>0 or InStr(strKey,"　")<>0 or InStr(strKey,"’")<>0 or InStr(strKey,chr(34))<>0 or InStr(strKey,"\")<>0 or InStr(strKey,",")<>0 or InStr(strKey,"<")<>0 or InStr(strKey,">")<>0 then
　　　　　　Response.Redirect "error.htm"
　　　　End If

　　　　lngLenKey=Len(strKey)
　　　　Select Case lngLenKey
　　　　　　Case 0　 ’若为空串，转到出错页
　　　　　　　　Response.Redirect "error.htm"　
　　　　　　Case 1　 ’若长度为1，则不设任何值
　　　　　　　　strNew1=""
　　　　　　　　strNew2=""
　　　　　　Case Else　’若长度大于1，则从字符串首字符开始，循环取长度为2的子字符串作为查询条件
　　　　　　　　For i=1 To lngLenKey-(lngSubKey-1)
　　　　　　　　　　strSubKey=Mid(strKey,i,lngSubKey)
　　　　　　　　　　strNew1=strNew1 & " or U_Name like ’%" & strSubKey & "%’"
　　　　　　　　　　strNew2=strNew2 & " or U_Info like ’%" & strSubKey & "%’"
　　　　　　　　Next
　　　　End Select

　　　　’得到完整的SQL语句
　　　　AutoKey="Select * from T_Sample where U_Name like ’%" & strKey & "%’ or U_Info like ’%" & strKey & "%’" & strNew1 & strNew2

　　End Function
　　%>
　　要实现智能搜索，其核心就是将搜索关键字进行自动分组。在此处，我们使用了循环取长度为2的子串的方法。为什么不将子串长度定为1、3、4或其他呢？这是因为若子串长度小于2即为1时，会失去将关键字分组的功能，而若子串长度大于2，则会丢失一些词组。大家可以将 CONST lngSubKey=2改为其他数字试一试，孰优孰劣自见分晓。
　　最后，别忘了将数据连接关闭，以释放资源。
　　<%
　　　　CNN.Close
　　　　Set CNN=Nothing
　　%>
　　至此，这个智能搜索引擎已经完成了。你还可以将其继续完善，比如添加分页、突出显示等功能。好了，不耽误大家时间了，赶快去试一试吧。 ^_^